{
  description = "A very basic flake";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-21.05";
    utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, utils }:
    {
      overlay = final: prev: {
        strojnadzor = self.packages.${final.system}.strojnadzor;
      };

      nixosModules.strojnadzor = {
        imports = [ ./module.nix ];
        nixpkgs.overlays = [ self.overlay ];
      };
      nixosModule = self.nixosModules.strojnadzor;

      nixosConfigurations.strojnadzor = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.strojnadzor
          {
            networking.hostName = "strojnadzor";
            boot.isContainer = true;
            services.strojnadzor.enable = true;
          }
        ];
      };
    } // utils.lib.eachSystem [ "x86_64-linux" ] (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};
      in
        rec {
          devShell = pkgs.mkShell {
            name = "strojnadzor-env";
            buildInputs = [
              pkgs.nodejs
              pkgs.python38Packages.poetry
            ];
            shellHook = ''
              unset PYTHONPATH
            '';
          };

          packages.strojnadzor = pkgs.poetry2nix.mkPoetryApplication {
            projectDir = ./.;
            python = pkgs.python38;
          };
          defaultPackage = packages.strojnadzor;

          apps.strojnadzor = utils.lib.mkApp {
            drv = packages.strojnadzor;
          };
          defaultApp = apps.strojnadzor;

        }
    );
}